Microsoft Excel 2016 BIBLE (2016)

IN THIS CHAPTER

1. Getting an overview of Excel's data validation feature

2. Looking at practical examples of using data validation formulas

This chapter explores a useful Excel feature: data validation. Data validation enables you to add rules for what's acceptable in specific cells and allows you to add dynamic elements to your worksheet without using any macro programming.

About Data Validation

The Excel data validation feature allows you to set up rules that determine what can be entered into a cell. For example, you may want to limit data entry in a particular cell to whole numbers between 1 and 12. If the user makes an invalid entry, you can display a custom message, such as the one shown in Figure 26.1.

Figure 26.1 Displaying a message when the user makes an invalid entry.

Excel makes it easy to specify the validation criteria. You can also use a formula for more complex criteria.

Caution

The Excel data validation feature suffers from a potentially serious problem: if the user copies a cell that does not use data validation and pastes it to a cell that does use data validation, the data validation rules are deleted. In other words, the cell then accepts any type of data. This has always been a problem, and Microsoft still hasn't fixed it in Excel 2016.

Specifying Validation Criteria

To specify the type of data allowable in a cell or range, follow these steps:

1. Select the cell or range.

2. Choose Data Data Tools Data Validation. The Data Validation dialog box appears (see Figure 26.2).

Figure 26.2 The three tabs of the Data Validation dialog box.

3. Select the Settings tab.

4. Choose an option from the Allow drop-down list. The contents of the Data Validation dialog box change, displaying controls based on your choice. To specify a formula, select Custom.

5. Specify the conditions by using the displayed controls. Your selection in step 4 determines the other controls you can access.

6. (Optional) Select the Input Message tab and specify which message to display when a user selects the cell. You can use this optional step to tell the user what type of data is expected. If this step is omitted, no message will appear when the user selects the cell.

7. (Optional) Select the Error Alert tab and specify which error message to display when a user makes an invalid entry. The selection for Style determines what choices users have when they make invalid entries. To prevent an invalid entry, choose Stop. If this step is omitted, a standard message will appear if the user makes an invalid entry.

Caution

Even with data validation in effect, a user can enter invalid data. If the Style setting on the Error Alert tab of the Data Validation dialog box is set to anything other than Stop, invalid data can be entered. You can identify invalid entries by having Excel circle them (explained in the next section).

8. Click OK. The cell or range contains the validation criteria you specified.

Types of Validation Criteria You Can Apply

From the Settings tab of the Data Validation dialog box, you can specify a variety of data validation criteria. The following options are available from the Allow drop-down list. Keep in mind that the other controls on the Settings tab vary, depending on your choice from the Allow drop-down list.

· Any Value: Selecting this option removes any existing data validation. Note, however, that the input message, if any, still displays if the box is checked on the Input Message tab.

· Whole Number: The user must enter a whole number. You specify a valid range of whole numbers by using the Data drop-down list. For example, you can specify that the entry must be a whole number greater than or equal to 100.

· Decimal: The user must enter a number. You specify a valid range of numbers by refining the criteria from choices in the Data drop-down list. For example, you can specify that the entry must be greater than or equal to 0 and less than or equal to 1.

· List: The user must choose from a drop-down list of entries you provide. This option is useful, and I discuss it in detail later in this chapter (see “Creating a Drop-Down List”).

· Date: The user must enter a date. You specify a valid date range from choices in the Data drop-down list. For example, you can specify that the entered data must be greater than or equal to January 1, 2016, and less than or equal to December 31, 2016.

· Time: The user must enter a time. You specify a valid time range from choices in the Data drop-down list. For example, you can specify that the entered data must be later than 12:00 p.m.

· Text Length: The length of the data (number of characters) is limited. You specify a valid length by using the Data drop-down list. For example, you can specify that the length of the entered data be 1 (a single alphanumeric character).

· Custom: To use this option, you must supply a logical formula that determines the validity of the user's entry. (A logical formula returns either TRUE or FALSE.) You can enter the formula directly into the Formula control (which appears when you select the Custom option), or you can specify a cell reference that contains a formula. This chapter contains examples of useful formulas.

The Settings tab of the Data Validation dialog box contains two other check boxes:

· Ignore Blank: If selected, blank entries are allowed.

· Apply These Changes to All Other Cells with the Same Setting: If selected, the changes you make apply to all other cells that contain the original data validation criteria.

Tip

The Data Data Tools Data Validation drop-down list contains an item named Circle Invalid Data. When you select this item, circles appear around cells that contain incorrect entries. If you correct an invalid entry, the circle disappears. To get rid of the circles, choose Data Data Tools Data Validation Clear Validation Circles. In Figure 26.3, valid entries are defined as values between 1 and 100. Values that are not within this numerical range are circled.

Figure 26.3 Excel can draw circles around invalid entries (in this case, cells that contain values greater than 100).

Creating a Drop-Down List

One of the most common uses of data validation is to create a drop-down list in a cell. Figure 26.4 shows an example that uses the month names in A1:A12 as the list source.

Figure 26.4 This drop-down list (with an Input Message) was created using data validation.

To create a drop-down list in a cell, follow these steps:

1. Enter the list items into a single-row or single-column range. These items will appear in the drop-down list.

2. Select the cell that will contain the drop-down list and then choose Data Data Tools Data Validation. The Data Validation dialog box appears.

3. From the Settings tab, select the List option (from the Allow drop-down list) and specify the range that contains the list, using the Source control. The range can be in a different worksheet, but it must be in the same workbook.

Tip

If you will be adding new items to the list, put the items in a single-column table that was created by using Insert Tables Table. Then Excel will update the list of options when you add or remove items from the table column.

4. Make sure that the In-Cell Dropdown check box is selected.

5. Set any other Data Validation options as desired.

6. Click OK. The cell displays an input message (if specified) and a drop-down arrow when it's activated. Click the arrow and choose an item from the list that appears.

Tip

If you have a short list, you can enter the items directly into the Source control of the Settings tab of the Data Validation dialog box. (This control appears when you choose the List option in the Allow drop-down list.) Just separate each item with list separators specified in your regional settings (a comma if you use the U.S. regional settings).

Unfortunately, you cannot control the font size used in drop-down lists. If the cell that displays the drop-down is formatted to show large text, the drop-down list does not use that formatting. If you zoom out on a worksheet, it may be difficult to read the items.

Using Formulas for Data Validation Rules

For simple data validation, the data validation feature is quite straightforward and easy to use. The real power of this feature, though, becomes apparent when you use data validation formulas.

The formula that you specify must be a logical formula that returns either TRUE or FALSE. If the formula evaluates to TRUE, the data is considered valid and remains in the cell. If the formula evaluates to FALSE, a message box appears that displays the message that you specify on the Error Alert tab of the Data Validation dialog box.

Specify a formula in the Data Validation dialog box by selecting the Custom option from the Allow drop-down list of the Settings tab. Enter the formula directly into the Formula control, or enter a reference to a cell that contains a formula. The Formula control appears on the Settings tab of the Data Validation dialog box when the Custom option is selected.

I present several examples of formulas used for data validation in the section “Data Validation Formula Examples,” later in this chapter.

Understanding Cell References

If the formula that you enter into the Data Validation dialog box contains a cell reference, that reference is considered a relative reference, based on the upper-left cell in the selected range.

The following example clarifies this concept. Suppose that you want to allow only an odd number to be entered into the range B2:B10. None of the Excel data validation rules can limit entry to odd numbers, so a formula is required.

Follow these steps:

1. Select the range (B2:B10 for this example) and ensure that cell B2 is the active cell.

2. Choose Data Data Tools Data Validation. The Data Validation dialog box appears.

3. Select the Settings tab and select the Custom option (from the Allow drop-down list).

4. Enter the following formula in the Formula field, as shown in Figure 26.5:

=ISODD(B2)

Figure 26.5 Entering a data validation formula.

This formula uses the ISODD function, which returns TRUE if its numeric argument is an odd number. Notice that the formula refers to the active cell, which is cell B2.

5. On the Error Alert tab, choose Stop for the Style and then type An odd number is required here in the Error Message field.

6. Click OK to close the Data Validation dialog box.

Notice that the formula entered contains a reference to the upper-left cell in the selected range. This data validation formula was applied to a range of cells, so you might expect that each cell would contain the same data validation formula. Because you entered a relative cell reference as the argument for the ISODD function, Excel adjusts the formula for the other cells in the B2:B10 range. To demonstrate that the reference is relative, select cell B5 and examine its formula displayed in the Data Validation dialog box. You'll see that the formula for this cell is

=ISODD(B5)

Note

An alternative method is to enter the logical formula into a cell and then enter a cell reference in the Formula field in the Data Validation dialog box. For this example, cell C2 would contain =ISODD(B2), and that formula would be copied down the column to cell C10. Then the Formula field in the Data Validation dialog box would have this formula: =C2. Most of the time, entering the formula into the Formula field is easier and more efficient.

Generally, when entering a data validation formula for a range of cells, you use a reference to the active cell, which is normally the upper-left cell in the selected range. An exception is when you need to refer to a specific cell. For example, suppose that you select range A1:B10, and you want your data validation to allow only values that are greater than the value in cell C1. You would use this formula:

=A1>$C$1

In this case, the reference to cell C1 is an absolute reference; it will not be adjusted for the cells in the selected range, which is just what you want. The data validation formula for cell A2 looks like this:

=A2>$C$1

The relative cell reference is adjusted, but the absolute cell reference is not.

Data Validation Formula Examples

The following sections contain a few data validation examples that use a formula entered directly into the Formula control on the Settings tab of the Data Validation dialog box. These examples help you understand how to create your own Data Validation formulas.

All the examples in this section are available at this book's website at www.wiley.com/go/excel2016bible. The file is named data validation examples.xlsx.

Accepting text only

Excel has a data validation option to limit the length of text entered into a cell, but it doesn't have an option to force text (rather than a number) into a cell. To force a cell or range to accept only text (no values), use the following data validation formula:

=ISTEXT(A1)

This formula assumes that the active cell in the selected range is cell A1.

Accepting a larger value than the previous cell

The following data validation formula enables the user to enter a value only if it's greater than the value in the cell directly above it:

=A2>A1

This formula assumes that A2 is the active cell in the selected range. Note that you can't use this formula for a cell in row 1.

Accepting nonduplicate entries only

The following data validation formula does not permit the user to make a duplicate entry in the range A1:C20:

=COUNTIF($A$1:$C$20,A1)=1

This is a logical formula that returns TRUE if the value in the cell occurs only one time in the A1:C20 range. Otherwise, it returns FALSE, and the Duplicate Entry dialog box is displayed.

This formula assumes that A1 is the active cell in the selected range. Note that the first argument for COUNTIF is an absolute reference. The second argument is a relative reference, and it adjusts for each cell in the validation range. Figure 26.6 shows this validation criterion in effect, using a custom error alert message. The user is attempting to enter 17 into cell B5.

Figure 26.6 Using data validation to prevent duplicate entries in a range.

Accepting text that begins with a specific character

The following data validation formula demonstrates how to check for a specific character. In this case, the formula ensures that the user's entry is a text string that begins with the letter A (uppercase or lowercase):

=LEFT(A1)="a"

This is a logical formula that returns TRUE if the first character in the cell is the letter A. Otherwise, it returns FALSE. This formula assumes that the active cell in the selected range is cell A1.

The following formula is a variation of this validation formula. It uses wildcard characters in the second argument of the COUNTIF function. In this case, the formula ensures that the entry begins with the letter A and contains exactly five characters:

=COUNTIF(A1,"A????")=1

Accepting dates by the day of the week

The following data validation formula assumes that the cell entry is a date, and it ensures that the date is a Monday:

=WEEKDAY(A1)=2

This formula assumes that the active cell in the selected range is cell A1. It uses the WEEKDAY function, which returns 1 for Sunday, 2 for Monday, and so on. Note that the WEEKDAY function accepts any nonnegative value as an argument (not just dates).

Accepting only values that don't exceed a total

Figure 26.7 shows a simple budget worksheet, with the budget item amounts in the range B1:B6. The planned budget is in cell E5, and the user is attempting to enter a value in cell B4 that would cause the total (cell E6) to exceed the budget. The following data validation formula ensures that the sum of the budget items does not exceed the budget:

=SUM($B$1:$B$6)<=$E$5

Figure 26.7 Using data validation to ensure that the sum of a range does not exceed a certain value.

Creating a dependent list

As I described previously, you can use data validation to create a drop-down list in a cell (see “Creating a Drop-Down List,” earlier in this chapter). This section explains how to use a drop-down list to control the entries that appear in a second drop-down list. In other words, the second drop-down list is dependent upon the value selected in the first drop-down list.

Figure 26.8 shows a simple example of a dependent list created by using data validation. Cell E2 contains data validation that displays a three-item list from the range A1:C1 (Vegetables, Fruits, and Meats). When the user chooses an item from the list, the second list (in cell F2) displays the appropriate items.

Figure 26.8 The items displayed in the list in cell F2 depend on the list item selected in cell E2.

This worksheet uses three named ranges:

· Vegetables: A2:A15

· Fruits: B2:B9

· Meats: C2:C5

Cell F2 contains data validation that uses this formula:

=INDIRECT($E$2)

Therefore, the drop-down list displayed in F2 depends on the value displayed in cell E2.